/[volute]/trunk/projects/vocabularies/configure.ac
ViewVC logotype

Contents of /trunk/projects/vocabularies/configure.ac

Parent Directory Parent Directory | Revision Log Revision Log


Revision 70 - (show annotations)
Fri Feb 22 05:00:49 2008 UTC (12 years, 9 months ago) by norman.x.gray
File size: 3440 byte(s)
Final preening before WD release 1.0

1 dnl
2 dnl Configure script for IVOA SKOS vocabularies
3 dnl
4 dnl Process this file with autoconf to generate the configure script
5
6 AC_INIT(ivoa-vocabularies, 1.0, norman@astro.gla.ac.uk)
7 AC_SUBST(RELEASEDATE, '2008 February 22') dnl ...as words
8 AC_SUBST(RELEASEDATEN, 2008-02-22) dnl ...as yyyy-mm-dd
9
10 dnl Distribution URI: this remains fixed as the 'latest version', or the
11 dnl top of the distribution/documentation tree
12 AC_SUBST(DISTURI, 'http://www.ivoa.net/Document/WD/vocabularies')
13 dnl Base URI for distribution -- no trailing slash
14 AC_SUBST(BASEURI, $DISTURI/vocabularies-$PACKAGE_VERSION)
15 dnl AC_SUBST(BASEURI, 'http://www.ivoa.net/Documents/ivoa-thesaurus-@PACKAGE_VERSION@')
16
17 dnl Issues list is currently not at the DISTURI
18 dnl AC_SUBST(ISSUESLIST, $DISTURI/issues)
19 AC_SUBST(ISSUESLIST, 'http://www.astro.gla.ac.uk/users/norman/ivoa/vocabularies/issues')
20
21 dnl The root file name of the distribution
22 AC_SUBST(DISTNAME, [vocabularies-$PACKAGE_VERSION])
23
24 # rapper can translate between RDF serialisations
25 # (part of Raptor: http://librdf.org/raptor/)
26 AC_PATH_PROGS(RAPPER, rapper)
27 AC_PATH_PROGS(PYTHON, python)
28 AC_PATH_PROGS(TAR, tar)
29 AC_PATH_PROGS(BIBTEX, bibtex)
30
31 dnl Handle --with-xsltproc[=path] and --with-saxon[=jarfile] options
32 process_xslt_with=xsltproc
33 AC_ARG_WITH([xsltproc],
34 [AS_HELP_STRING([--with-xsltproc],
35 [choose a non-default xsltproc executable])],
36 [dnl --with-xsltproc option given (as 'yes' if no option value)
37 if test "$with_xsltproc" = yes; then
38 AC_PATH_PROG(XSLTPROC, xsltproc)
39 else
40 AC_CHECK_FILE($with_xsltproc,
41 [AC_SUBST(XSLTPROC, $with_xsltproc)],
42 [AC_MSG_ERROR([Can't find file $with_xsltproc])])
43 fi],
44 [dnl no --with-xsltproc option given -- default
45 AC_PATH_PROG(XSLTPROC, xsltproc)])
46 AC_ARG_WITH([saxon],
47 [AS_HELP_STRING([--with-saxon],
48 [process XSLT using the named Saxon8 jar file])],
49 [if test "$with_saxon" = "yes"; then
50 AC_SUBST(SAXONJAR, [saxon8.jar])
51 else
52 AC_CHECK_FILE($with_saxon,
53 [],
54 [AC_MSG_WARN([The jar file $with_saxon does not exist])])
55 AC_SUBST(SAXONJAR, $with_saxon)
56 fi
57 process_xslt_with=saxon])
58
59 dnl Now add the conditionals
60 if test $process_xslt_with = saxon; then
61 AC_MSG_NOTICE([XSL transforms using Saxon])
62 AC_SUBST(USE_SAXON, [])
63 AC_SUBST(USE_XSLTPROC, [#])
64 else
65 AC_MSG_NOTICE([XSL transforms using xsltproc])
66 AC_SUBST(USE_SAXON, [#])
67 AC_SUBST(USE_XSLTPROC, [])
68 fi
69
70
71 # CWM will almost certainly have to be overridden on the command-line
72 # This appears to need the CVS version of cwm, available from
73 # <http://www.w3.org/2000/10/swap/doc/cwm.html> (the 1.0.0 `release'
74 # version seems to barf on @base directives in N3/Turtle files. That
75 # page points to other tools which can do similar work, but it's
76 # possible that the rules in src/code/checkHierarchy.n3 are specific to cwm.
77 #
78 # The default will work only if cwm is installed in a standard Python
79 # way (unknown to Norman), and the 'cwm' command is on the path (more details?).
80 test -n "$CWM" || CWM=cwm
81 AC_ARG_VAR(CWM, [invocation of the cwm script, eg 'python /path/to/cwm.py'])
82
83 AC_CONFIG_FILES([Makefile doc/Makefile src/Makefile src/README
84 src/AAkeys/Makefile
85 src/AOIM/Makefile
86 src/UCD/Makefile
87 src/IVOAT/Makefile
88 src/IAUT93/Makefile])
89
90 AC_OUTPUT

msdemlei@ari.uni-heidelberg.de
ViewVC Help
Powered by ViewVC 1.1.26